mirror of
https://github.com/Ralim/IronOS.git
synced 2025-02-26 07:53:55 +00:00
780f1f35ca
This patch makes allocating special pages automatic and flexible, allowing flash size and application start offset specification with linker command line arguments. It should allow easier porting to different targets and experimentation without adding code complexity. Many original STM32F103x8 chips have fully functional 128 kiB flash and so this additional space might come useful for experimentation, additional optional features etc. Tested on v2.51A board, including writing and verifying 128 kiB of random data. Make variables are added to control that, so to build for the full undocumented flash size and dapboot configured to start the app from 8 kiB offset one can run: make flash_size=128k bootldr_size=0x2000
170 lines
4.0 KiB
Plaintext
170 lines
4.0 KiB
Plaintext
|
|
|
|
/* Entry Point */
|
|
ENTRY(Reset_Handler)
|
|
|
|
/* Highest address of the user mode stack */
|
|
_estack = 0x20005000; /* end of RAM */
|
|
|
|
_Min_Heap_Size = 0x300; /* required amount of heap */
|
|
_Min_Stack_Size = 1024; /* required amount of stack */
|
|
|
|
__APP_BASE_ADDRESS__ = 0x08000000 + __BOOTLDR_SIZE__;
|
|
__ROM_REGION_LENGTH__ = __FLASH_SIZE__ - __BOOTLDR_SIZE__;
|
|
__FLASH_END_ADDR__ = __APP_BASE_ADDRESS__ + __ROM_REGION_LENGTH__;
|
|
|
|
/* Memories definition */
|
|
MEMORY
|
|
{
|
|
RAM (xrw) : ORIGIN = 0x20000000, LENGTH = 20K
|
|
ROM (rx) : ORIGIN = __APP_BASE_ADDRESS__, LENGTH = __ROM_REGION_LENGTH__
|
|
}
|
|
/* ROM is normally 48K after the bootloader, however we allocate the last page for settings, and the second last one for display boot logo*/
|
|
|
|
/* Sections */
|
|
SECTIONS
|
|
{
|
|
/* The startup code into ROM memory */
|
|
.isr_vector :
|
|
{
|
|
. = ALIGN(4);
|
|
KEEP(*(.isr_vector)) /* Startup code */
|
|
. = ALIGN(4);
|
|
} >ROM
|
|
|
|
/* The program code and other data into ROM memory */
|
|
.text :
|
|
{
|
|
. = ALIGN(4);
|
|
*(.text) /* .text sections (code) */
|
|
*(.text*) /* .text* sections (code) */
|
|
*(.glue_7) /* glue arm to thumb code */
|
|
*(.glue_7t) /* glue thumb to arm code */
|
|
*(.eh_frame)
|
|
|
|
KEEP (*(.init))
|
|
KEEP (*(.fini))
|
|
|
|
. = ALIGN(4);
|
|
_etext = .; /* define a global symbols at end of code */
|
|
} >ROM
|
|
|
|
/* Constant data into ROM memory*/
|
|
.rodata :
|
|
{
|
|
. = ALIGN(4);
|
|
*(.rodata) /* .rodata sections (constants, strings, etc.) */
|
|
*(.rodata*) /* .rodata* sections (constants, strings, etc.) */
|
|
. = ALIGN(4);
|
|
} >ROM
|
|
|
|
.ARM.extab : {
|
|
. = ALIGN(4);
|
|
*(.ARM.extab* .gnu.linkonce.armextab.*)
|
|
. = ALIGN(4);
|
|
} >ROM
|
|
|
|
.ARM : {
|
|
. = ALIGN(4);
|
|
__exidx_start = .;
|
|
*(.ARM.exidx*)
|
|
__exidx_end = .;
|
|
. = ALIGN(4);
|
|
} >ROM
|
|
|
|
.preinit_array :
|
|
{
|
|
. = ALIGN(4);
|
|
PROVIDE_HIDDEN (__preinit_array_start = .);
|
|
KEEP (*(.preinit_array*))
|
|
PROVIDE_HIDDEN (__preinit_array_end = .);
|
|
. = ALIGN(4);
|
|
} >ROM
|
|
|
|
.init_array :
|
|
{
|
|
. = ALIGN(4);
|
|
PROVIDE_HIDDEN (__init_array_start = .);
|
|
KEEP (*(SORT(.init_array.*)))
|
|
KEEP (*(.init_array*))
|
|
PROVIDE_HIDDEN (__init_array_end = .);
|
|
. = ALIGN(4);
|
|
} >ROM
|
|
|
|
.fini_array :
|
|
{
|
|
. = ALIGN(4);
|
|
PROVIDE_HIDDEN (__fini_array_start = .);
|
|
KEEP (*(SORT(.fini_array.*)))
|
|
KEEP (*(.fini_array*))
|
|
PROVIDE_HIDDEN (__fini_array_end = .);
|
|
. = ALIGN(4);
|
|
} >ROM
|
|
|
|
/* Used by the startup to initialize data */
|
|
_sidata = LOADADDR(.data);
|
|
|
|
/* Initialized data sections into RAM memory */
|
|
.data :
|
|
{
|
|
. = ALIGN(4);
|
|
_sdata = .; /* create a global symbol at data start */
|
|
*(.data) /* .data sections */
|
|
*(.data*) /* .data* sections */
|
|
|
|
. = ALIGN(4);
|
|
_edata = .; /* define a global symbol at data end */
|
|
} >RAM AT> ROM
|
|
|
|
.logo_page (NOLOAD) :
|
|
{
|
|
. = ABSOLUTE(__FLASH_END_ADDR__ - 2048);
|
|
KEEP (*(.logo_page*))
|
|
} > ROM
|
|
|
|
.settings_page (NOLOAD) :
|
|
{
|
|
. = ABSOLUTE(__FLASH_END_ADDR__ - 1024);
|
|
KEEP (*(.settings_page*))
|
|
} > ROM
|
|
|
|
.bss :
|
|
{
|
|
/* Uninitialized data section into RAM memory */
|
|
. = ALIGN(4);
|
|
/* This is used by the startup in order to initialize the .bss secion */
|
|
_sbss = .; /* define a global symbol at bss start */
|
|
__bss_start__ = _sbss;
|
|
*(.bss)
|
|
*(.bss*)
|
|
*(COMMON)
|
|
|
|
. = ALIGN(4);
|
|
_ebss = .; /* define a global symbol at bss end */
|
|
__bss_end__ = _ebss;
|
|
} >RAM
|
|
|
|
/* User_heap_stack section, used to check that there is enough RAM left */
|
|
._user_heap_stack :
|
|
{
|
|
. = ALIGN(8);
|
|
PROVIDE ( end = . );
|
|
PROVIDE ( _end = . );
|
|
. = . + _Min_Heap_Size;
|
|
. = . + _Min_Stack_Size;
|
|
. = ALIGN(8);
|
|
} >RAM
|
|
|
|
|
|
|
|
/* Remove information from the compiler libraries */
|
|
/DISCARD/ :
|
|
{
|
|
libc.a ( * )
|
|
libm.a ( * )
|
|
libgcc.a ( * )
|
|
}
|
|
|
|
.ARM.attributes 0 : { *(.ARM.attributes) }
|
|
}
|